pipeline {
    agent any

    environment {
        GITEA_REPO_PATH = "lucas/reverse-proxy"
        GITEA_API_URL = "https://gitea.lucasroyer.fr/api/v1"
        DOCKER_HOST = "unix:///run/user/1001/docker.sock"
    }

    stages {
        stage('Check git...') {
            steps {
                checkout scm
            }
        }
        stage('Build') {
            steps {
                echo "Build Caddy with cache plugin..."
                sh "docker compose build --pull"
            }
        }
        stage('Deploy') {
            steps {
                echo "Deploy new reverse proxy..."
                sh "docker compose up -d"
            }
        }
        stage('Check module...') {
            steps {
                script {
                    // Ask caddy to list modules
                    def modules = sh(script: "docker exec caddy-reverse-proxy caddy list-modules", returnStdout: true)
                    if (modules.contains('http.handlers.cache')) {
                        echo "Cache module activated"
                    } else {
                        error "Error : can't find cache module"
                    }
                }
            }
        }
    }

    post {
        always {
            script {
                echo "Send Gitea check..."
                // Get and store SHA
                def commitSha = sh(script: 'git rev-parse HEAD', returnStdout: true).trim()
                
                // Convert from Jenkins to Gitea API
                def buildState = (currentBuild.currentResult == 'SUCCESS') ? 'success' : 'failure'
                def buildDesc  = (currentBuild.currentResult == 'SUCCESS') ? 'Build successful' : 'Build failed'

                // Send it to Gitea API with secret 'gitea-token'
                withCredentials([string(credentialsId: 'gitea-token', variable: 'GITEA_TOKEN')]) {
                    // Use \$TOKEN to avoid jenkins to print token in logs
                    sh """
                        curl -f -X POST "${GITEA_API_URL}/repos/${GITEA_REPO_PATH}/statuses/${commitSha}" \
                             -H "Authorization: token \$GITEA_TOKEN" \
                             -H "Content-Type: application/json" \
                             -d '{"state": "${buildState}", "target_url": "${env.BUILD_URL}", "description": "${buildDesc}", "context": "jenkins-ci"}'
                    """
                }
            }
            echo "Clean unused image..."
            sh "docker image prune -f"
        }
        success { echo "Success !" }
        failure { echo "Failed." }
    }
}